NUNCA MAIS PASSE RAIVA POR NÃO CONSEGUIR RESOLVER UM PROBLEMA COM O EXCEL - GARANTIDO!

UNIVERSIDADE DO VBA - Domine o VBA no Excel Criando Sistemas Completos - Passo a Passo - CLIQUE AQUI

Você está em: PrincipalArtigos › ASP 3.0 › Capítulo 11 : 02
Quer receber novidades e e-books gratuitos?
« Lição anterior Δ Página principal ¤ Capítulos Próxima lição »
SITES DINÂMICOS COM ASP 3.0 - CURSO COMPLETO
Autor: Júlio Battisti


Promoção: Livro Windows Server 2012 R2 e Active Directory - Curso Completo, 2100 Páginas. Tudo para você se tornar um administrador de redes altamente qualificado para o mercado de trabalho e levar a sua carreira para o próximo nível!

Promoção: Livro Windows Server 2012 R2 e Active Directory

Curso Completo, 2100 páginas.

Tudo para você se tornar um administrador de redes altamente qualificado para o mercado de trabalho e levar a sua carreira para o próximo nível!

MAIS DETALHES | COMPRAR ESTE LIVRO


Lição 084 - Capítulo 11 - O objeto FileSystemObject

O objeto FileSystemObject nos fornece  uma série de recursos para acesso ao sistema de arquivos do Servidor, através de nossas páginas ASP. Com os recursos oferecidos por este objeto, podemos manipular arquivos de texto, pastas e drives a partir do código ASP.

Para criarmos um objeto do tipo FileSystemObject, podemos utilizar a seguinte sintaxe:

Set  nome_objeto = Server.CreateObject(“Scripting.FileSystemObject”)

Por exemplo, podemos criar um objeto chamado fileobj:

Set fileobj  = Server.CreateObject(“Scripting.FileSystemObject”)

Agora vamos passar ao estudo da propriedade e dos métodos deste objeto.

Propriedade do objeto FileSystemObject.

Temos uma única propriedade que é a propriedade Drives, a qual retorna todos os drives disponíveis no servidor IIS onde a página está gravada, inclusive drives de rede mapeados.

Considere o próximo fragmento de código:

<%

                ' O primeiro passo é a criação do objeto FileSystemObject.

                Set fileobj=Server.CreateObject("Scripting.FileSystemObject")

                For each drive in fileobj.Drives

                    Response.Write drive & "<BR>"

                Next

 %>

Este fragmento produz a saída indicada na Figura 11.1:

Curso Completo de ASP 3.0 - Júlio Battisti
Figura 11.1 Resultado produzido pelo uso da propriedade Drives.

Agora vamos passar ao estudo dos métodos do objeto FileSystemObject.

Métodos do objeto FileSystemObject.

Este objeto apresenta uma série de métodos, os quais facilitam o trabalho com drives, pastas e arquivos. Por isso iremos dividir a apresentação dos métodos, conforme os mesmos se destinam ao trabalho com drives, pastas ou arquivos.

Métodos do objeto FileSystemObject para trabalho com Drives.

Temos três métodos para tratar com Drives:

  • O método DriveExist: Este método retorna True se o drive passado como parâmetro existe e False caso contrário. O parâmetro passado para este método pode ser uma letra de drive (inclusive de um drive mapeado), uma string de texto ou o caminho completo para uma pasta ou arquivo.

Para drives de dispositivos removíveis, como um CD-ROM ou um ZIP Drive, este método retorna True, mesmo que não exista uma mídia no drive.

Podemos utilizar a propriedade IsReady do objeto Drive para determinar se o mesmo está pronto para ser acessado. No exemplo do CD-ROM, podemos utilizar a propriedade IsReady para determinar se existe ou não um CD-ROM no drive de CD. Aprenderemos a utilizar a propriedade IsReady quando estudarmos o objeto Drive mais adiante neste capítulo.

A seguir temos um exemplo de utilização deste método:

<%

                Set fileobj = CreateObject("Scripting.FileSystemObject")

                If fileobj.DriveExists(“X:”) Then

                               Response.Write “Drive X: Existe !!”

                Else

                               Response.Write “Drive X: Não Existe !!”

                 End If

%>

  • O método GetDrive: Este método retorna um objeto do tipo Drive, correspondente ao caminho passado como parâmetro. Podemos passar como parâmetro a identificação de um drive, como por exemplo: “d”, “d:”, “d:\” ou um caminho para um drive da rede, no tradicional formato \\nome_do_computador\nome_do_compartilhamento.

Estudaremos o objeto Drive mais adiante neste capítulo.

A seguir temos um exemplo de utilização deste método:

<%

                Set drive = fileobj.GetDrive("E:")

               

                 'Agora vamos calcular o espaço livre no drive E:

                 espaco=(drive.freespace)/(1024*1024)

                 Response.Write "Espaço livre em E: " & FormatNumber(espaco,0) & " MB"

%>

Neste exemplo utilizamos a propriedade freespace do objeto Drive e a dividimos duas vezes por 1024 para obter o espaço livre em MB. Depois utilizamos a função FormatNumber, para exibir o valor obtido sem as casas decimais. O resultado deste trecho de código é algo do tipo:

Espaço livre em E: 1.070 MB

  • O método GetDriveName: Este método retorna o nome do drive que foi passado como parâmetro.

A seguir temos um exemplo de utilização deste método.

<%

                ' O primeiro passo é a criação do objeto FileSystemObject.

                Set fileobj=Server.CreateObject("Scripting.FileSystemObject")

                For each drive in fileobj.Drives

                    Response.Write drive & "<BR>"

                    Response.Write “Nome do drive: “ & fileobj.GetDriveName(drive) & “ <BR>”

                Next

 %>

Com isso encerramos o estudo dos métodos para tratamento de Drives.

Métodos do objeto FileSystemObject para trabalho com pastas:

Temos dez métodos para tratar com Pastas.

  • Método BuildPath(caminho,nome): Este método adiciona o arquivo ou pasta especificado no parâmetro nome, à pasta especificada no parâmetro caminho. Caso seja necessário, o método adiciona o separador de pastas “\”.

Considere o seguinte exemplo:

<%

                Set fileobj=Server.CreateObject("Scripting.FileSystemObject")

                novapasta = fileobj.BuildPath("C:\","pasta123")

                Response.Write novapasta

%>

Este fragmento produz a seguinte saída: C:\pasta123.

É importante observar que a pasta C:\pasta123 não será criada pela utilização deste método. Apenas estamos atribuindo à variável novapasta, o caminho C:\pasta123.  Para criar uma nova pasta, podemos utilizar o método CreateFolder, que veremos logo adiante.

  • O método CopyFolder “fonte”,”destino”,substituir: Copia uma ou mais pastas especificadas no parâmetro fonte. Podemos copiar mais do que um pasta, pois podemos utilizar caracteres curinga, como por exemplo C:\documentos\*. As pastas de origem são copiadas para a pasta especificada pelo parâmetro destino. Todos os arquivos contidos nas pastas de origem serão copiados para o destino. O parâmetro substituir é opcional. Ele pode conter os valores True ou False. Este parâmetro especifica se arquivos já existentes no destino devem ou não ser sobrescritos. Se a pasta de destino já existe e o parâmetro substituir é definido em Falso, irá ocorrer um erro. O valor padrão para o parâmetro substituir é True.

IMPORTANTE: Somente podemos utilizar caracteres curinga na parte final do caminho. Considere o seguinte exemplo:

FileSystemObject.CopyFolder "c:\mydocuments\letters\*", "c:\tempfolder\"

Porém o próximo exemplo está incorreto:

FileSystemObject.CopyFolder "c:\mydocuments\*\*", "c:\tempfolder\"

Se a pasta de destino ainda não existe a pasta de destino e todo o seu conteúdo será copiado. Obviamente que a pasta de destino será criada.

Se o parâmetro de destino for o nome de um arquivo existente, ocorrerá um erro.

Se o destino for o nome de uma pasta, o método tentará copiar a pasta de origem e todo o seu conteúdo para a pasta de destino. Se um arquivo que está sendo copiado já existir na pasta de destino e o parâmetro substituir estiver definido como False, irá ocorrer um erro. Caso contrário, o arquivo do diretório de origem será copiado sobre o arquivo do diretório de destino.

O método CopyFolder para na ocorrência do primeiro erro. Nenhuma tentativa de reverter as alterações que já foram feitas será efetuada, isto é, os arquivos que foram copiados antes da ocorrência do erro não serão eliminados da pasta de destino.

Considere o seguinte exemplo:

fileobj.CopyFolder "C:\meus documentos","C:\teste"

Esta linha de código irá copiar todo o conteúdo da pasta C:\meus documentos, para a pasta c:\teste. Caso a pasta C:\teste não exista, a mesma será automaticamente criada antes que a cópia seja efetuada.

  • O método CreateFolder(nomepasta): Este método cria uma pasta de acordo com o parâmetro que foi passado para o mesmo. Caso a pasta já existe, será gerado um erro.

O exemplo a seguir, cria uma pasta chamada c:\teste123

fileobj.CreateFolder("C:\teste123")

Caso a pasta já exista obteremos a mensagem de erro indicada na Figura 11.2.

Curso Completo de ASP 3.0 - Júlio Battisti
Figura 11.2 Erro gerado pelo método CreateFolder quando a pasta já existe.

  • O método DeleteFolder(pastaname,force): Este método elimina a pasta especificada no parâmetro pastaname e todo o seu conteúdo. O parâmetro force pode ser True ou False. Este parâmetro determina se o conteúdo de uma pasta que possui o atributo de somente leitura é para ser deletado ou não. O valor padrão é False.

Será gerado um erro se a pasta especificada pelo parâmetro pastaname não for encontrado. Este método encerra a sua execução na ocorrência do primeiro erro, sendo que as alterações que já foram feitas não serão desfeitas.

Considere o exemplo.

fileobj.DeleteFolder("C:\teste123")

este comando elimina a pasta C:\teste123.

Caso a pasta a ser eliminada não exista, obteremos a mensagem de erro indicada na Figura 11.3.

Curso Completo de ASP 3.0 - Júlio Battisti
Figura 11.3 Erro gerado pelo método DeleteFolder quando a pasta não existe.

  • O método FolderExists(nomepasta): Este método retorna True se a pasta passada como parâmetro existe e False caso contrário. O parâmetro nomepasta pode conter um caminho absoluto ou relativo.

Considere o exemplo abaixo:

<%

                Set fileobj=Server.CreateObject("Scripting.FileSystemObject")

                For each drive in fileobj.Drives

                        Response.Write drive & "<BR>"

                        caminho=fileobj.BuildPath(drive,"\meus documentos")

                    If fileobj.FolderExists(caminho) then

                           Response.Write "<B>Este drive possui a pasta Meus documentos<B> <HR>"

                    Else

                          Response.Write "<B>Este drive não possui a pasta Meus documentos <B><HR>"

                     End If

             Next

 %>

Este fragmento produz o resultado indicado na Figura 11.4:

Curso Completo de ASP 3.0 - Júlio Battisti
Figura 11.4 Utilizando o método FolderExists.

  • O método GetAbsolutePathName(parâmetro): Este método recebe como parâmetro o nome de uma pasta ou outra especificação de caminho válida, e retorna o caminho completo para esta pasta, tendo como base a pasta atual.  Por exemplo, se a pasta atual for C:\meus documentos e o parâmetro passado para este método for “cartas”, o valor de retorno será C:\meus documentos\cartas.

Vamos a mais alguns exemplos para esclarecer o comportamento deste método. Vamos supor que a pasta atual é c:\meus documentos\cartas. Na Tabela 11.1 temos alguns exemplos de retorno deste método:

Parâmetro Valor de retorno
"C:" “C:\meus documentos\cartas”
"C:.." “C:\meus documentos”
"C:\\\" "C:\"
"C:*.*\abril96" “C:\meus documentos\cartas\*.*\abril96”
"filial5" “C:\meus documentos\cartas\filial5”

Tabela 11.1 Valores de retorno do método GetAbsolutePathName.

  • O método GetFolder(caminhopasta): Retorna um objeto do tipo Folder, correspondente a pasta que foi passada como parâmetro. Ocorrerá um erro se a pasta passada como parâmetro não existir. Estudaremos o objeto Folder em detalhes ainda neste capítulo.

Considere o seguinte exemplo:

<%

                ' O primeiro passo é a criação do objeto FileSystemObject.

                Set fileobj=Server.CreateObject("Scripting.FileSystemObject")

                Set pasta=fileobj.GetFolder("C:\meus documentos")

                For each subpasta in pasta.subfolders

                      Response.Write subpasta & "<HR>" 

                Next

 %>

O resultado deste fragmento de código é indicado na Figura 11.5.

Curso Completo de ASP 3.0 - Júlio Battisti
Figura 11.5 Utilizando o método GetFolder.

Observe que já utilizamos a coleção subfolders do objeto Folder. Conforme citado anteriormente, estudaremos o objeto Folder em detalhes, ainda neste capítulo.

  • O método GetParentFolderName(pasta):  Este método retorna uma String com o nome da pasta na qual está contida a pasta ou arquivo passado como parâmetro. Este método não faz a verificação para saber se a pasta existe ou não. Se a pasta ou arquivo já estiver na raiz do drive, será retornada uma String de tamanho zero.

Considere o exemplo:

pastacontem = fileobj.GetParentFolderName(“C:\meus documentos\word”)

este comando retorna na variável pastacontem a string C:\meus documentos.

  • O método GetSpecialFolder(folderespvalor): Retorna um objeto do tipo Folder, correspondente a um dos tipos especiais de pasta do Windows. Os valores possíveis para folderespvalor são os seguintes:

0             Pasta da Windows

1             Pasta de Sistema

2             Pasta temporária               

Considere o exemplo a seguir:

<%

                ' O primeiro passo é a criação do objeto FileSystemObject.

                Set fileobj=Server.CreateObject("Scripting.FileSystemObject")

                Set temppasta=fileobj.GetSpecialFolder(2)

%>

Com este fragmento de código, criamos um objeto do tipo Folder, o qual está ligado a pasta temporária do Windows e pode ser acessado pela variável temppasta.

  • O método MoveFolder(origem,destino): Move a pasta especificada no parâmetro origem, para a pasta especificada no parâmetro destino. Podemos incluir caracteres curinga na origem, porém não no destino.

Se a origem contém caracteres curinga ou o destino termina com o caracter “\”, o método MoveFolder considera que o destino representa o nome de uma pasta já existente, para a qual deve ser movida a pasta de origem. Caso contrário o método assume que o parâmetro destino especifica o nome de uma pasta que deve ser criada e para a qual deve ser movido o conteúdo da pasta de origem. Em ambos os casos, devemos considerar o seguinte:

1.            Se a pasta de destino não existe, a pasta de origem será movida, sendo que a pasta de destino será criada antes, pelo próprio método MoveFolder.

2.            Se o parâmetro destino for o nome de um arquivo, será gerado um erro.

3.            Se o parâmetro destino for o nome de uma pasta que já existe, será gerado um erro.

O método MoveFolder será interrompido na ocorrência do primeiro erro. Quaisquer alterações que tenham sido feitas, não serão revertidas.

Considere o exemplo:

fileobj.MoveFolder “C:\teste1”, "C:\teste2"

Com isso encerramos o estudo dos métodos para tratamento de Pastas.

Métodos do objeto FileSystemObject para trabalho com arquivos:

Temos onze métodos para tratar com Arquivos.

  • Método CopyFile(origem,destino,substituir): Copia um ou mais arquivos especificados pelo parâmetro origem (podemos utilizar caracteres curinga) para a pasta especificada no parâmetro destino.

Se a origem contém caracteres curinga ou o destino termina com o caracter “\”, o método CopyFile considera que o destino representa o nome de uma pasta já existente, para a qual deve ser copiados os arquivos especificados pelo parâmetro origem. Caso contrário o método assume que o parâmetro destino especifica o nome de um arquivo que deve ser criado. Em ambos os casos, devemos considerar o seguinte:

1.            Se a pasta de destino não existe, os arquivos especificados no parâmetro origem serão copiados, sendo que a pasta de destino será criada antes, pelo próprio método CopyFile.

2.            Se o parâmetro destino for o nome de um arquivo que já existe, será gerado um erro caso o parâmetro substituir esteja definido como False, caso contrário o arquivo existente será substituído.

3.            Se o parâmetro destino for o nome de uma pasta , será gerado um erro.

O método CopyFile será interrompido na ocorrência do primeiro erro. Quaisquer alterações que tenham sido feitas, não serão revertidas.

A seguir temos um exemplo de utilização do método CopyFile:

FileSystemObject.CopyFile "c:\meus documentos\oficios\*.doc", "e:\copia de segurança\oficios\"

  • O método CreateTextFile(nomearquivo,substituir,unicode): Este método cria o arquivo de texto especificado pelo parâmetro nomearquivo e retorna um objeto do tipo TextStream, o qual pode ser utilizado para gravar informações no arquivo e ler informações do arquivo.

O parâmetro substituir pode assumir os valores True e False. Quando este parâmetro tiver o valor True, se o arquivo já existir o mesmo será eliminado e um novo arquivo será criado. O padrão para o parâmetro substituir é False. Este parâmetro é opcional.

O parâmetro unicode pode assumir os valores True e False. Se este parâmetro tiver o valor True, o texto será salvo com caracteres unicode, os quais utilizam dois bytes por caractere, ao invés de um byte por caracter como é o caso do padrão ASCII. O valor padrão para o parâmetro unicode é False. Este parâmetro é opcional.

Considere o exemplo a seguir:

<%

                   Set fileobj=Server.CreateObject("Scripting.FileSystemObject")

                   Set arqtexto = fileobj.CreateTextFile("c:\teste.txt",true)

                   arqtexto.WriteLine("*************************")

                   arqtexto.writeline("LINHA 1 DO TEXTO")

                   arqtexto.writeline("LINHA 2 DO TEXTO")

                   arqtexto.writeline("LINHA 3 DO TEXTO") 

                   arqtexto.writeline("*************************")

%>

Este fragmento de código cria um objeto do tipo TextStream, o qual é associado a variável arqtexto. Depois utilizamos o método writeline para escrever linhas de texto no arquivo c:\teste.txt.

Na Figura 11.6 temos o conteúdo do arquivo teste.txt, após a execução do código do nosso exemplo.

Curso Completo de ASP 3.0 - Júlio Battisti
Figura 11.6 Utilizando o método CreateTextFile.

  • O método DeleteFile(arquivo,force): Este método elimina um ou mais arquivos definidos pelo parâmetro arquivo. Podem ser utilizados caracteres curinga. O parâmetro force pode assumir os valores True ou False. Se o parâmetro force for definido como True, o arquivo será eliminado mesmo se tiver o atributo de Somente leitura marcado. O valor padrão do atributo force é False.

Se o arquivo especificado não for encontrado, será gerado um erro. O método DeleteFile será interrompido na ocorrência do primeiro erro. Quaisquer alterações que tenham sido feitas, não serão revertidas.

Considere o exemplo:

fileobj.DeleteFile(“C:\meus documentos\oficio.doc”,true)

  • O método FileExists(arquivo): Este método retorna True se o arquivo passado como parâmetro existe, caso contrário o método irá retornar Falso.

Considere o seguinte exemplo:

<%

                If fileobj.FileExists(“C:\meus documentos\relatorio.doc”) Then

                      Response.Write “O arquivo com o relatório já foi salvo na pasta Meus documentos”

                Else

                      Response.Write “O arquivo com o relatório ainda não foi salvo na pasta Meus documentos”

                End If

%>

  • O método GetBaseName(arquivo): Este método retorna apenas o nome do arquivo passado como parâmetro, sem a extensão ou qualquer informação de caminho.

Considere o exemplo:

<%

       Response.Write fileobj.GetBaseName(“C:\meus documentos\vendas.xls”)

%>

Este comando retorna apenas vendas.

  • O método GetExtensionName(arquivo): Este método retorna apenas a extensão do arquivo passado como parâmetro. Uma string de tamanho zero “ “ será retornada se o arquivo passado como parâmetro não for encontrado.

Considere o exemplo:

<%

       Response.Write fileobj.GetExtensionName(“C:\meus documentos\vendas.xls”)

%>

Este comando irá retornar apenas xls.

  • O método GetFile(arquivo): Este método retorna um objeto do tipo File e ligado ao arquivo passado como parâmetro. Se o arquivo passado como parâmetro não existir, será gerado um erro.

Iremos estudar o objeto File em detalhes, ainda neste capítulo.

Considere o exemplo:

<%

                Set fileobj=Server.CreateObject("Scripting.FileSystemObject")

                Set arquivo=fileobj.GetFile("C:\autoexec.bat")

                Response.Write "Caminho do arquivo: " & arquivo.path & "<HR>"

                Response.Write "Data de criação: " & arquivo.DateCreated & "<HR>"

                Response.Write "Data último acesso: " & arquivo.DateLastAccessed & "<HR>"

%>

O resultado deste fragmento de código é indicado na Figura 11.7.

Curso Completo de ASP 3.0 - Júlio Battisti
Figura 11.7 Utilizando o método GetFile.

Observe que já utilizamos algumas propriedades do objeto File. Conforme descrito anteriormente, iremos estudar o objeto File ainda neste capítulo.

  • O método GetFileName(caminho): Retorna o nome do último arquivo ou pasta que foi especificado no parâmetro caminho. Por exemplo se passarmos C:\meus documentos\clientes.mdb como parâmetro será retornado clientes.mdb. Já se passarmos c:\meus documentos, será retornado meus documentos. Se o parâmetro passado não terminar com o nome de uma pasta ou arquivo, o método GetFileName retornará uma string de tamanho zero “ “.

Este método não verifica se o caminho passado como parâmetro existe ou não.

  • O método GetTempName( ): Retorna o nome de um arquivo ou pasta, nome este que é gerado randomicamente. Este arquivo ou pasta pode ser utilizado para operações que necessitam de um local de armazenamento temporário.

Este método não cria um arquivo temporário. Ele apenas gera um nome que pode ser utilizado pelo método CreateTextFile, o qual pode ser usado para criar o arquivo.

Considere o exemplo:

<%

                Set fileobj=Server.CreateObject("Scripting.FileSystemObject")

                tempname=fileobj.GetTempName

                Set txttemp=fileobj.CreateTextFile(tempname)

%>

  • O método MoveFile(origem, destino): Este método pode ser utilizado para mover o arquivo passado no parâmetro origem, para a localização especificada no parâmetro destino. Podemos utilizar caracteres curinga na origem, porém não no destino.

Se a origem contém caracteres curinga ou o destino termina com o caracter “\”, o método MoveFile considera que o destino representa o nome de uma pasta já existente, para a qual deve ser movido o arquivo de origem. Caso contrário o método assume que o parâmetro destino especifica o nome de uma pasta e arquivo para o qual deve ser movido o arquivo de origem. Em ambos os casos, devemos considerar o seguinte:

1.            Se o destino não existe, o arquivo de origem será movido, sendo que a pasta de destino será criada antes, pelo próprio método MoveFile.

2.            Se o parâmetro destino for o nome de um arquivo existente, será gerado um erro.

3.            Se o parâmetro destino for o nome de uma pasta , será gerado um erro.

O método MoveFile será interrompido na ocorrência do primeiro erro. Quaisquer alterações que tenham sido feitas, não serão revertidas.

Considere o exemplo:

<%

                Set fileobj=Server.CreateObject("Scripting.FileSystemObject")

                fileobj.MoveFile “C:\teste.txt”, “D:\documentos\teste.txt”

%>

  • O método OpenTextFile(arquivo,iomode,create,format): Cria um arquivo com o nome passado no parâmetro arquivo ou abre um arquivo existente. Este método retorna um objeto do tipo TextStream que faz referência ao arquivo especificado pelo parâmetro arquivo.

O parâmetro iomode determina o tipo de acesso que teremos ao arquivo. Os valores permitidos para este parâmetro são os seguintes:

1             ForReading          Somente para leitura. Este é o valor padrão.

2             ForWriting            Somente para escrita. Não podemos ler o conteúdo já existente.

8.            ForAppending      Abre o arquivo e grava informações no final do mesmo.

Se o parâmetro create for definido como True quando tentarmos Escrever ou Adicionar (Appending) conteúdo a um arquivo que não existe, um novo arquivo será criado. O valor padrão para este parâmetro é falso.

O parâmetro format pode assumir os seguintes valores:

0             TristateFalse                        Abre o arquivo como sendo ASCII. É o valor padrão.

-1            TristateTrue                         Abre o arquivo como sendo Unicode

-2            TristateUseDefault             Abre o arquivo utilizando o formato padrão do sistema.

Considere o exemplo:

<%

                Set fileobj=Server.CreateObject("Scripting.FileSystemObject")

                Set arquivo = fileobj.OpenTextFile("c:\testfile.txt", ForWriting, True)

%>

Com isso finalizamos o estudo dos métodos relacionados com arquivos e também o estudo do objeto FileSystemObject. Agora iniciaremos o estudo dos objetos Drive, Folder e File.


Promoção: Livro Windows Server 2012 R2 e Active Directory - Curso Completo, 2100 Páginas. Tudo para você se tornar um administrador de redes altamente qualificado para o mercado de trabalho e levar a sua carreira para o próximo nível!

Promoção: Livro Windows Server 2012 R2 e Active Directory

Curso Completo, 2100 páginas.

Tudo para você se tornar um administrador de redes altamente qualificado para o mercado de trabalho e levar a sua carreira para o próximo nível!

MAIS DETALHES | COMPRAR ESTE LIVRO


« Lição anterior Δ Página principal ¤ Capítulos Próxima lição »
Quer receber novidades e e-books gratuitos?

Cursos Online

  • Banco de Dados
  • Carreira
  • Criação/Web
  • Excel/Projetos
  • Formação
  • + Todas as categorias
  • Contato: Telefone: (51) 3717-3796 | E-mail: webmaster@juliobattisti.com.br | Whatsapp: (51) 99627-3434

    Júlio Battisti Livros e Cursos Ltda | CNPJ: 08.916.484/0001-25 | Rua Vereador Ivo Cláudio Weigel, 537 - Universitário, Santa Cruz do Sul/RS, CEP: 96816-208

    Todos os direitos reservados, Júlio Battisti 2001-2019 ®

    [LIVRO]: MACROS E PROGRAMAÇÃO VBA NO EXCEL 2010 - PASSO-A-PASSO

    APRENDA COM JULIO BATTISTI - 1124 PÁGINAS: CLIQUE AQUI