Lição 18: Worksheet e Range – Propriedades e Métodos – Parte II

Referir-se a células relativas a outras células:

 

Uma maneira comum de trabalhar com uma célula em relação a uma outra célula é usar a propriedade Offset. No exemplo seguinte, o conteúdo da célula que se encontra uma linha abaixo e a três colunas da célula ativa na planilha ativa é formatado com sublinhado duplo.

 

    ActiveCell.Offset(1, 3).Font.Underline = xlDouble

 

Observação: Você pode gravar macros que usem a propriedade Offset em vez de referências absolutas. No menu Ferramentas, aponte para Gravar macro e, em seguida, clique em Usar referências relativas.

 

Para fazer um loop através de um intervalo de células, use uma variável com a propriedade Cells em um loop. O exemplo seguinte preenche as 20 primeiras células da terceira coluna com valores entre 5 e 100, incrementados por 5. A variável counter é usada como índice de linha para a propriedade Cells.

 

   Dim counter As Integer

    For counter = 1 To 20

        Worksheets("Sheet1").Cells(counter, 3).Value = counter * 5

    Next counter

 

Referir-se a células usando um objeto Range:

 

Quando você define uma variável de objeto para um objeto Range, você pode facilmente manipular o intervalo usando o nome da variável.

 

O exemplo seguinte cria a variável de objeto myRange e, em seguida, atribui a variável ao intervalo A1:D5 de Sheet1 na pasta de trabalho ativa. Instruções subseqüentes modificam propriedades do intervalo substituindo o objeto de intervalo pelo nome da variável.

 

    Dim myRange As Range

    Set myRange = Worksheets("Sheet1").Range("A1:D5")

    myRange.Formula = "=RAND()"

    myRange.Font.Bold = True

 

Referir-se a todas as células da planilha:

 

Quando você aplica a propriedade Cells a uma planilha sem especificar um número de índice, o método retorna um objeto Range representando todas as células da planilha. O exemplo seguinte limpa o conteúdo de todas as células de Sheet1 na planilha ativa.

 

Worksheets("Sheet1").Cells.ClearContents

Referir-se a vários intervalos:

 

Usando o método apropriado, você pode facilmente referir-se a vários intervalos. Use os métodos Range e Union para referir-se a qualquer grupo de intervalos; use a propriedade Areas para referir-se ao grupo de intervalos selecionado em uma planilha.

 

Usar a propriedade Range:

 

Você pode referir-se a vários intervalos com a propriedade Range colocando vírgulas entre duas ou mais referências. O exemplo seguinte limpa o conteúdo dos três intervalos de Sheet1.

 

    Worksheets("Sheet1").Range("C5:D9,G9:H16,B14:D18").ClearContents

 

Os intervalos nomeados tornam o uso da propriedade Range mais fácil ao trabalhar com vários intervalos. O exemplo seguinte funciona quando todos os três intervalos nomeados se encontram na mesma planilha.

 

 Range("MyRange, YourRange, HisRange").ClearContents

 

Usar o método Union:

 

Você pode combinar vários intervalos em um objeto Range usando o método Union. O exemplo seguinte cria um objeto Range chamado myMultipleRange, define-o com os intervalos A1:B2 e C3:D4 e, em seguida, formata com negrito os intervalos combinados.

 

    Dim r1, r2, myMultipleRange As Range

    Set r1 = Sheets("Sheet1").Range("A1:B2")

    Set r2 = Sheets("Sheet1").Range("C3:D4")

    Set myMultipleRange = Union(r1, r2)

    myMultipleRange.Font.Bold = True

 

Usar a propriedade Áreas:

 

Você pode usar a propriedade Areas para referir-se ao intervalo selecionado ou à coleção de intervalos em uma seleção de várias áreas. O exemplo seguinte conta as áreas da seleção. Se houver mais de uma área, uma mensagem de aviso será exibida.

 

    If Selection.Areas.Count > 1 Then

        MsgBox "A operação não é permitida em uma selação múltipla."

    End If

Todos os direitos reservados: ® Júlio Battisti, 2002